无线网卡转热点管理(批处理)

@echo off

title Virtual WiFi Miniport Adapter Manager

set TempFile=%SystemRoot%\System32\%Random%.temp
( echo benhon.org >%TempFile% ) 1>nul 2>nul
if exist %TempFile% ( del %TempFile% 1>nul 2>nul ) else ( goto UAC_ )

set SSID=BENHON
set PASSWORD=12345678

:MENU_
cls
echo Microsoft Virtual WiFi Miniport Adapter Manager v1.1
echo.
echo                  Powered by Benhon / 13th Sep. 2012
echo.
echo.
echo [1] Virtual WiFi Adapter - Turn On
echo [2] Virtual WiFi Adapter - Turn Off
echo [3] Virtual WiFi Adapter - Setup
echo [4] Virtual WiFi Adapter - Remove
echo [5] Virtual WiFi Adapter - Allowable ?
echo [6] Internet Connection Sharing
echo [7] Exit
echo.
set /p answer= Choose:
if %answer%==1 goto ON_
if %answer%==2 goto OFF_
if %answer%==3 goto INSTALL_
if %answer%==4 goto REMOVE_
if %answer%==5 goto DRVINFO_
if %answer%==6 goto ICS_
if %answer%==7 goto EXIT_
goto ERROR_

:ON_
cls
netsh wlan start hostednetwork
pause
goto MENU_

:OFF_
cls
netsh wlan stop hostednetwork
pause
goto MENU_

:INSTALL_
cls
echo Setup SSID to default value "%SSID%". (Press Enter to Apply)
echo Or type the ssid:
echo.
set /p SSID=
echo.
echo Setup Password to default value "%PASSWORD%". (Press Enter to Apply)
echo Or type the password (8 Characters):
echo.
set /p PASSWORD=
echo.
pause
goto :INSTALL2_

:INSTALL2_
cls
echo Will Start "Virtual WiFi Adapter" With These Parameters ?
echo.
echo * SSID: %SSID%
echo * Password: %PASSWORD%
echo.
echo [1] Yes
echo [2] Restet
echo [3] Back to Menu
echo [4] Exit :(
echo.
set /p answer=
if %answer%==1 goto INSTALL3_
if %answer%==2 goto INSTALL_
if %answer%==3 goto MENU_
if %answer%==4 goto EXIT_
goto ERROR_

:INSTALL3_
cls
echo Starting "Virtual WiFi Adapter" ...
netsh wlan set hostednetwork mode=allow ssid="%SSID%" key=%PASSWORD% keyUsage=persistent
echo Done !!!
echo.
pause
goto MENU_

:REMOVE_
cls
echo Do you want remove "Virtual WiFi Adapter" ?
echo.
echo [1] Yes
echo [2] No
set /p answer=
if %answer%==1 goto REMOVE2_
if %answer%==2 goto MENU_
goto ERROR_

:REMOVE2_
cls
echo Uninstalling "Virtual WiFi Adapter" ...
netsh wlan set hostednetwork mode=disallow
echo Done :(
echo.
pause
goto MENU_

:DRVINFO_
cls
netsh wlan show drivers
pause
goto MENU_

:ICS_
cls
control netconnections
goto MENU_

:ERROR_
cls
echo ERROR !!!
echo.
pause
goto MENU_

:UAC_
cls
echo Please run as administrator !!!
echo.
pause
goto EXIT_

:EXIT_
exit

版权声明：本文为原创文章，版权归 BenhoN 所有。

本文链接：https://blog.benhon.net/archives/143.html

所有原创文章采用知识共享 署名-非商业性使用 4.0 国际 许可协议进行许可，你可以自由地转载和修改，但请务必注明文章来源并且不可用于商业目的。